Typische Schülerwünsche

Zuerst sollten Schüler die ganze Welt erstellen, mit allen Objekten und Räumen, die dazu gehören. Wenn ein Objekt existieren, aber nicht zugänglich sein soll, gibt man einfach keinen Ort dazu an. Dann ist es nirgendwo.

Danach gibt es Sonderwünsche. Die meisten lassen sich mit Instead-Regeln erfüllen.

Hier kommst du nicht vorbei: Einen Ausgang blockieren

Instead of going east from the garden:
	if the player is carrying the magic thingy:
		say "Yes! You may pass!";
		continue the action;
	otherwise:
		say "No. You need a certain magic item."

Statt east kann da auch jede andere konkrete Himmelsrichtung stehen, oder anywhere für jede beliebige erlaubte Himmelsrichtung. Nowhere bezieht sich auf nicht erlaubte Himmelsrichtungen, also wo standardmäßig die Antwort kommt “You can’t got that way.”
Statt garden kann da jeder andere Raum stehen.

Modifiziert werden können Instead-Regeln zum Beispiel durch die Ergänzung: for the first/second/third time, wobei jeweils der Versuch zählt und nicht der Erfolg.

Die Bedingung kann zum Beispiel so aussehen:

	if the player is wearing the crown [also: wenn er sie anhat]:
	if the player is carrying the crown [also: wenn er sie mit sich führt, aber nicht anhat]:
	if the player has the crown [anhaben oder mit sich führen]:
	if the box contains the diamond:
	if the table supports the candle:
	if the player is in the garden:
	if the box is in the garden:
	if the box is in the location of the player:

Etwas verschwinden oder erscheinen lassen

Instead of giving the coin to the man:
	remove the coin from play;
	say "The man takes your money and gives you an apple.";
	now the apple is in the location of the player.	[oder: move the apple to the location of the player]

oder wenn der Apfel gleich beim Spieler landen soll:

		now the apple is carried by the player [oder: now the player carries the apple].

Etwas einkaufen

Siehe oben. Man sollte aber eher mit Objekten wie a coin, a dollar bill oder a ten-dollar-bill arbeiten und nicht mit “ten dollars”. Geld kann Inform zwar auch, aber das ist schwieriger.

Aktionen, für die man Regeln aufstellen kann

Instead-Regeln gelten jeweils für bestimmte Aktionen. Aktionen sind quasi die Tätigkeiten, die die Spielfigur in der Spielwelt ausüben kann. Die meisten haben ein Objekt (genannt the noun), manche haben zwei (the noun, the second noun), manche keines.

Die wichtigsten Aktionen sind vielleicht:

  • examining (something/the apple/something that is not edible)
  • taking (the coin/anything)
  • opening (the box/a container)
  • eating (the poison apple)
  • kissing (the frog)
  • pulling/pushing/turning (something)
  • giving (the apple) to (somebody/the princess)

Als Quasi-Argument einer solchen Regel kann entweder ein konkretes Objekt stehen (the apple) oder eine Klasse (a container), eine Himmelsrichtung (east) oder eine durch Adjektive oder Relativsätze näher bestimmte Art von Objekten (a container which is open). Außerdem können die Wörter something/anything für beliebige Objekte der Klasse thing, somewhere/anywhere für beliebige Himmelsrichtungen und somebody/anybody für beliebige Objekte der Klasse person (man, woman, animal) verwendet werden.

Mit Leuten reden

Wenn Nichtspielecharaktere selber etwas tun oder Aufträge entgegen nehmen und – vielleicht – ausführen, sind sie lebensechter, aber auch schwerer zu programmieren. Auch intelligente Dialoge sind möglich, aber anspruchsvoll. Einfache Gespräche gehen mit den Aktionen asking somebedy about topic und telling somebody about topic so:

Suzy is a woman in the House. The ring is a thing carried by Suzy.
Instead of asking Suzy about "herself/Suzy":
	say "She say's her name is Suzy."
Instead of asking Suzy about "a/the ring" for the first time:
	say "Do you like the ring? You can have it.";
	say "(She gives you the ring.)";
	now the player carries the ring.

Ein Nachteil ist, dass man a) wissen muss, wonach man fragen kann, b) die Person zustandslos ist, also auf die gleiche Frage immer die gleiche Antwort gibt (deswegen auch der Zusatz “for the first time”). Die topics in Anführungszeichen sind reine Strings, sobald ein Zeichen in der Frage anders ist als in der vorgesehenen Zeichenkette, wird die Frage nicht mehr erkannt. Schrägstriche geben Alternativen zwischen einzelnen Wörtern an (und nur zwischen denen).

Oder man verzichtet auf topics und lässt als einzige Möglichkeit “talk to Suzy” zu. Dazu muss man erst eine neue Aktion erfinden: 

Talking to is an action applying to one visible thing.
Understand "talk to [someone]" as talking to.
Check talking to: say "[The noun] doesn't reply."

Instead of talking to Suzy:
	say "[one of]'Hello,' you greet her.[paragraph break]'Hi!' she replies. [or]You introduce yourself.[paragraph break]'My name is Suzy,' she tells you.[or]'You have an interesting ring,' you say.[paragraph break]Suzy looks at the ring. 'Do you like it? You can have it.' [paragraph break]She gives you the ring.[or]You have nothing more to talk about with Suzy at the moment.[stopping]".

Dann muss der Spieler immer nur “talk to Suzy” eingeben, und kriegt der Reihe nach die Antworten bis zur letzten. Beim dritten Mal steht dort, dass Suzy dem Spieler den Ring gibt. Bisher steht das aber nur da und ist noch nicht implementiert.

Am einfachsten geht das mit einer Zusatzregel:

Before talking to Max for the third time:
	now the player carries the ring.

Das Mitzählen übernimmt Inform dabei selber.

Schreibe einen Kommentar